The circuit to be analyzed is described by a text file called a netlist. The first line in the netlist is ignored, that is, it is assumed to be a comment. The last line of the netlist is usually simply the line ".END", but this can be omitted. Any lines after the line ".END" are ignored.
The order of the lines between the comment and end is irrelevant. Lines can be comments, circuit element declarations or simulation directives. Let's start with an example:
* This first line is ignored
* The circuit below represents an RC circuit driven
* with a 1MHz square wave signal
R1 n1 n2 1K ; a 1KOhm resistor between nodes n1 and n2
C1 n2 0 100p ; a 100pF capacitor between nodes n2 and ground
V1 n1 0 PULSE(0 1 0 0 0 .5μ 1μ) ; a 1Mhz square wave
.tran 3μ ; do a 3μs long transient analysis
.end
The first two lines are comments. Any line starting with a "*" is a comment and is ignored. The line starting with "R1" declares that there is a 1K resistor connected between nodes n1 and n2. Note that the semicolon, ";", can be used to start a comment in the middle of a line. The line starting with "C1" declares that there is a 100pF capacitor between nodes n2 and ground. The node "0" is the global circuit common ground.
Below is an overview of the lexicon of LTspice:
o Letter case, leading spaces, blanks, and tabs are ignored.
o The first non-blank character of a line defines the type of circuit element.
| Leading Character | Type of line |
| * | Comment |
| A | Special function device |
| B | Arbitrary behavioral source |
| C | Capacitor |
| D | Diode |
| E | Voltage dependent voltage source |
| F | Current dependent current source |
| G | Voltage dependent current source |
| H | Current dependent voltage source |
| I | Independent current source |
| J | JFET transistor |
| K | Mutual inductance |
| L | Inductor |
| M | MOSFET transistor |
| O | Lossy transmission line |
| Q | Bipolar transistor |
| R | Resistor |
| S | Voltage controlled switch |
| T | Lossless transmission line |
| U | Uniform RC-line |
| V | Independent voltage source |
| W | Current controlled switch |
| X | Subcircuit Invocation |
| Z | MESFET or IGBT transistor |
| . | A simulation directive, For example: .options reltol=1e-4 |
| + | A continuation of the previous line. The "+" is removed and the remainder of the line is considered part of the prior line. |
Numbers can be expressed not only in scientific notation; e.g., 1e12; but also using engineering multipliers. That is, 1000.0 or 1e3 can also be written as 1K. Below is a table of understood multipliers:
| Suffix | Multiplier |
| T | 1e12 |
| G | 1e9 |
| Meg | 1e6 |
| K | 1e3 |
| mil | 25.4e-6 |
| m | 1e-3 |
| u(or μ) | 1e-6 |
| n | 1e-9 |
| p | 1e-12 |
| f | 1e-15 |
The suffixes are not case sensitive. Unrecognized letters immediately following a number or engineering multiplier are ignored. Hence, 10, 10V, 10Volts, and 10Hz all represent the same number, and M, MA, MSec, and MMhos all represent the same scale factor(.001). A common error is to draft a resistor with value of 1M, thinking of a one Megaohm resistor, however, 1M is interpreted as a one milliohm resistor. This is necessary for compatibility with standard SPICE practice.
LTspice will accept numbers written in the form 6K34 to mean 6.34K. This works for any of the multipliers above. It can be turned off by going to Tools=>Control Panel=>SPICE and unchecking "Accept 3K4 as 3.4K".
Nodes names may be arbitrary character strings. Global circuit common node(ground) is "0", though "GND" is special synonym. Note that since nodes are character strings, "0" and "00" are distinct nodes.
Throughout the following sections of the manual, angle brackets are placed around data fields that need to be filled with specific information; for example, "<srcname>" would be the name of some specific source. Square brackets indicate that the enclosed data field is optional.